Screenshot Management Using the "V" Key

[Ragtopjohnny]

Hello...

 

I was wondering if there is such a way that you can create new folders with the screen shot management system or set up paths to different folders for different flights rather than just having every image bundled together?

 

Thanks in advance, I hope so, I hate seperating them after every flight and FS Berlin Screenshot manager does not work with DX10.

 

Maybe some alternative screen shot programs could be listed that do work with it? Thanks!

 

John

[fxsttcb]

I use Martin Wrights "MultiGrab". :D Bottom of page: http://www.mwgfx.co.uk/index.htm

Create a folder, point the app to it and hit the Prt Scr key.

Dunno about DX10, but, supports almost all graphic formats...Don

[Ragtopjohnny]

Thanks Don! I'll give it a try, can't hurt! :)

[Jim Robinson]

I wrote a batch file to manage mine, it uses nconvert.exe (free utility) to convert them all to .jpg. It gives you an option to specify an output folder, creates the folder if it doesn't exist already, and also allows you to specify output filenames such as KSFO_KGEG_001.jpg, KSFO_KGEG_002.jpg, etc. I'm a little reluctant to post this here because I worry that some less than computer savvy person will screw somehing up and then I'll be in trouble for it, lol. I'm not sure there's anything that can be screwed up, if there is I don't know what it would be. I have been using this for almost a year now and it works well for me so here goes:

 

@echo off
setlocal EnableDelayedExpansion
title Screenshot Wizard
mode con: Cols=82 Lines=32
if not exist nconvert.exe goto nconvert_error
if exist *.jpg md $$$temp_hold
move *.jpg $$$temp_hold
cls
echo.
echo.
echo     The wizard will create a folder for the processed jpegs
echo     and store them there when finished, please type a name for
echo     that folder and press enter...
echo.
echo.
set /p output_folder=
if not exist "%output_folder%" md "%output_folder%"
cls
echo.
echo.
echo     "%output_folder%" has been created.
echo.
echo     The wizard can rename the output files with a prefix + sequential number
echo     for example "KLAS-KLAX_001.jpg", "KLAS-KLAX_002.jpg", etc.
echo     Select an option below:
echo.
echo.
echo     [1] Yes, I want to rename the output files
echo     [2] No, keep the original filenames
echo.
echo.
set /p file_rename=
if %file_rename%==1 goto yes_rename
if %file_rename%==2 goto no_rename



:yes_rename
cls
echo.
echo.
echo     Please type a prefix for the output sequence, for example
echo     typing KLAX_ will result in filenames like KLAX_001.jpg,
echo     KLAX_002.jpg, etc.
echo.
echo.
set /p prefix=
set num=999
nconvert -out jpeg *.bmp
for %%f in (*.jpg) do (
set /a num=!num!+1
ren "%%f" "!prefix!!num:~1,3!.jpg"
)
>nul move *.jpg "%output_folder%"
if exist $$$temp_hold move $$$temp_hold\*.jpg
if exist $$$temp_hold rd /q $$$temp_hold
cls
echo.
echo.
echo     .jpgs have been processed and moved to "%output_folder%"
echo     would you like to delete the source .bmps now?
echo.
echo.
echo     [1] Yes
echo     [2] No
set /p del=
if %del%==1 goto yes_delete
if %del%==2 goto no_delete



:no_rename
cls
nconvert -out jpeg *.bmp
>nul move *.jpg "%output_folder%"
if exist $$$temp_hold move $$$temp_hold\*.jpg
if exist $$$temp_hold rd /q $$$temp_hold
cls
echo.
echo.
echo     .jpgs have been processed and moved to "%output_folder%"
echo     would you like to delete the source .bmps now?
echo.
echo.
echo     [1] Yes
echo     [2] No
set /p del=
if %del%==1 goto yes_delete
if %del%==2 goto no_delete


:yes_delete
>nul del *.bmp
cls
echo.
echo.
echo     .bmps deleted, finished, closing in 2 seconds...
>nul timeout /t 2
exit

:no_delete
cls
echo.
echo.
echo     .bmps not deleted, finished, closing in 2 seconds...
>nul timeout /t 2
exit

:nconvert_error
cls
echo.
echo.
echo     nconvert.exe was not found, the wizard cannot continue. Place a
echo     copy of nconvert.exe into the Pictures\Flight Simulator X Files
echo     folder and restart the wizard. Nothing has been changed, press
echo     spacebar to exit.
>nul pause
exit

 

In addition to the batch file you also need a copy of nconvert.exe which you can find with google, place it in your Pictures\Flight Simulator X Files folder along with the batch file. The batch file will abort without changing anything if it can't find nconvert.exe.

 

 

The wizard will walk you through the following screens:

 

 

First you must specify an output folder, to specify a folder within the Pictures\Flight Simulator X Files folder simply type a folder name, for example "screenshots 11-11-14" and a Pictures\Flight Simulator X Files\screenshots 11-11-14 folder will be created. Here I've specified a temporary folder on drive D:\ instead.

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard01.jpg

 

 

 

Select an option to rename or keep the original filenames given by the FSX V-key here. Press the corresponding number key on your keyboard ([1] or [2]) and press "Enter" to select an option.

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard02.jpg

 

 

 

Choosing option "1" above takes you to this screen where you specify a prefix for the output sequence. Here I've specified "FSX_cleanout_111114_" as the prefix, pressing "Enter" at this point starts the conversion.

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard03.jpg

 

 

 

Nconvet.exe doing the dirty work, it took about 5 seconds to process 80 .bmps in this example

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard04.jpg

 

 

 

After the .jpgs have been converted, renamed, and moved to the specified output folder you are given an option to delete the original v-key .bmps or you can leave them intact to deal with them manually

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard05.jpg

 

 

 

Here is the output from the example shown. The total filesize of the 80 .bmps I just converted was 656 Mb, after conversion the .jpgs consume only 24 Mb. The output pixel dimensions are unchanged, if the input .bmps were 1920x1080 the output .jpgs will also be 1920x1080 and if you do a comparison between the two you'll find it very difficult to detect a difference in quality if it's possible at all. You'll likely want to resize and/or edit any images you plan on posting anyway and by the time you get through that it will be impossible to detect any loss in quality.

 

http://www.cat-tamer.com/flightsim/atchmnts/screenshot_wizard06.jpg

 

 

Note that this is untested beyond my own PC, it's unlikely that it can screw anything up although it will delete all your original v-key .bmps if you select option 1 on the last screen. For that reason I suggest using option #2 ("No": leave .bmps intact) until you can verify that the batch file is utilizing nconvert.exe properly and correctly outputting .jpgs.

 

Also, in the event that you have .jpgs in your Pictures\Flight Simulator X Files folder prior to running the screenshot wizard, the wizard will create a temporary folder before it does anything and temporarily move those .jpgs there for safe keeping. After running and moving the finished .jpgs to the output folder it will move the pre-existing .jpgs back and delete the temporary folder. In this case, if you specified output directly into the Pictures\Flight Simulator X Files folder and you also specified the same file prefix that the pre-existing .jpgs had, it's possible that some of your freshly converted .jpgs could potentially be overwritten by those returning from the temporary folder. Use "don't delete .bmps" and always specify an output folder other than Pictures\Flight Simulator X Files and you should be OK.

 

Use at your own risk, I'm only posting this in case someone here finds it useful, I really don't care if anyone uses it or not, I'm not pushing it, I'm not saying it's a better way than anything else, I'm just showing the way I do it is all. If you're gun shy with batch files and/or untrusting of amateur coders that's perfectly fine with me, just close the tab for this thread and move on with my blessing.

 

Jim

[PhantomTweak]

Personally, I use ScreenHunter v4.0 There is also a v5 out, but it's payware, and I'm a cheap SOB...errr.....FRUGAL, verrry frugal!

It's available in the library here, and on Simviation, and Avsim.

Pat☺

[Jim Robinson]

Can you confirm that works in DX10 though? Print screen usually just captures a black image in full-screen DX10 so you're more or less forced to use the V key and process the captures afterwards. I know FSScreen doesn't work, that's the only one I've tried but I suspect any where you use the print screen key would give the same result. They'd probably work in windowed mode though.

[PhantomTweak]

Can you confirm that works in DX10 though?

 

If you mean the ScreenHunter program, I can neither confirm, nor deny, it's functionality in DX10. All I have to use/test things in, is FS9. Like I said, I'm VERY frugal :)

This is a seperate program that grabs the screen, or you can have it grab selectable portions of the screen. The key utilized for capture is selectable in the program, as is where you stick the resultant pictures. Also selectable is the form of the pic, whether JPG, BMP, etc. I like it. It's usefull, easy to set up, runs in the background, and doesn't affect the game in the slightest when used. Can't even tell sometimes, unless I go check, that it did in fact take the capture :)

All I can say about it. One way to find out about it though: Install it and try it! Who knows :)

Pat☺